Um Chat via Bluetooth para Android, MacOS e Windows

Posted by on in Blogs

File:ClassicBluetoothVsLowEnergyBluetooth.png

Introdução

A inspiração para este artigo surgiu durante uma POC que estamos fazendo com um cliente implementando uma solução RFID com mobile.

Mas qual a relação do RFID com Bluetooth? Bem, a principio nenhuma relação direta, exceto pelo fato de que a ampla maioria dos leitores RFID que suportam integração para mobile (Android) o fazem via comunicação Bluetooth SPP (serial port profile).

Bluetooth SPP é um dos muitos profiles suportados pela tecnologia Bluetooth. Na prática, estamos falando de comunicação serial (socket) sobre Bluetooth. Neste link você encontra uma lista de todos os profiles suportados oficialmente pelo Bluetooth standard, lembrando que diferentes devices suportam diferentes conjuntos de profiles.

Com isso chegamos ao chat via Bluetooth…

Bluetooth no Delphi e C++ Builder

O RAD Studio oferece suporte nativo para Bluetooth e BluetoothLE (low energy). Apenas para contextualizar, BluetoothLE é diferente de Bluetooth, e se presta a outras necessidadesd – principalmente a implementações de dispositivos IoT, como beacons e etc…

Voltando ao Bluetooth standard, este que você utiliza quando faz o pareamento de dois devices, ou ainda de seu smartphone com o rádio de seu carro, observe que no título do artigo não está mencionado suporte para iOS, e por uma razão bastante simples: o iOS não implementa Bluetooth SPP.

Por qual razão? Bem, perdemos a oportunidade de perguntar ao Steve (Jobs), então temos que nos contentar apenas com esta lista de profiles suportados: https://support.apple.com/en-us/HT204387.

Obviamente há uma explicação científica para o tema. Caso alguém saiba mais a respeito, acrescente aos comentários deste artigo!Com isso, o suporte a Bluetooth e BLE no RAD Studio também apresenta esta “limitação”, digamos assim.

Mais detalhes sobre versões e protocolos Bluetooth no Delphi e C++ estão neste link da documentação: http://docwiki.embarcadero.com/RADStudio/Tokyo/en/Using_Bluetooth.

Código pelo Amor de Deus?

Sim, já estamos chegando lá. Mas esta teoria é importante para compreender o que estamos fazendo.Para estabelecer uma conexão utilizando SPP, leia-se porta serial, utilizamos basicamente uma conexão socket, muito parecido com qualquer solução socket que você já tenha implementado.

Quando estabelecemos uma conexão socket via Bluetooth (formalmente um rfcomm server e respectivo client), devemos especificar um UUID. Esse cara funciona como um identificador único para que o client possa se conectar ao serviço correto, já que podemos criar múltiplos canais de comunicação de maneira simultânea. Uma boa discussão sobre este tema você encontra aqui: http://stackoverflow.com/questions/13964342/android-how-do-bluetooth-uuids-work.

Basicamente, existem algumas UUID previamente definidos (https://www.bluetooth.com/specifications/assigned-numbers/service-discovery), os quais atendem serviços específicos, e você pode definir seu próprio identificar para uma aplicação em particular.

Felizmente nosso TBluetooth implementa tudo o que precisamos, e de maneira simples – só pra variar ?

Agora sim, código!

Antes de mais nada, lembre-se que os devices devem estar devidamente pareados para que a conexão Bluetooth ocorra. Existem forma de automatizar o pareamento, mas não para todas as plataformas.

Em linhas gerais, do ponto de vista do “client”, tudo que temos que fazer é estabelecer a conexão socket, e então enviar o que desejamos.Já do lado “server”, utilizaremos um TTask para manter o Socket Server “ouvindo” em segundo plano.

Este é o conceito geral.

Aqui temos o código de ambas as classes, um “writer” e um “reader“:

unit uBlueChat;

interface

uses SysUtils, System.Classes, System.StrUtils, System.Threading,
  System.Bluetooth, System.Types, System.Generics.Collections,
{$IFDEF MACOS}
  Macapi.CoreFoundation,
{$ENDIF}
  FMX.Memo;

type
  TTextEvent = procedure(const Sender: TObject; const AText: string;
    const aDeviceName: string) of object;

type
  TBlueChatWriter = class(TComponent)
  private
    fSendUUID: TGUID;

    fDeviceName: string;
    fBlueDevice: TBluetoothDevice;

    fSendSocket: TBluetoothSocket;
    procedure SetBlueDevice(Value: string);
  public
    constructor Create(AOwner: TComponent); override;

    function SendMessage(sMessage: string): boolean;
    property DeviceName: string read fDeviceName write SetBlueDevice;
  end;

type
  TBlueChatReader = class(TComponent)
  private
    fReadUUID: TGUID;

    fDeviceName: string;
    fTaskReader: ITask;

    fReadSocket: TBluetoothSocket;
    fServerSocket: TBluetoothServerSocket;

    FOnTextReceived: TTextEvent;
    procedure SetOnTextReceived(const Value: TTextEvent);
  public
    constructor Create(AOwner: TComponent); override;
    procedure StartReader;
    procedure StopReader;

    property OnTextReceived: TTextEvent read FOnTextReceived
      write SetOnTextReceived;
    property DeviceName: string read fDeviceName write fDeviceName;
  end;

implementation

{ TBlueChatSend }

const
  cTimeOut: integer = 5000;

function FindBlueDevice(DeviceName: string): TBluetoothDevice;
var
  i: integer;
  aBTDeviceList: TBluetoothDeviceList;
begin
  aBTDeviceList := TBluetoothManager.Current.CurrentAdapter.PairedDevices;
  for i := 0 to aBTDeviceList.Count - 1 do
    if aBTDeviceList.Items[i].DeviceName = DeviceName then
      exit(aBTDeviceList.Items[i]);
  Result := nil;
end;

constructor TBlueChatWriter.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  fBlueDevice := nil;
  fSendSocket := nil;

  fSendUUID := StringToGuid('{14800546-CF05-481F-BE41-4EC0246D862D}');
end;

function TBlueChatWriter.SendMessage(sMessage: string): boolean;
begin
  try
    try
      if fBlueDevice = nil then
        raise Exception.Create('Select a bluetooth device first...');

      fSendSocket := fBlueDevice.CreateClientSocket(fSendUUID, False);
      if fSendSocket = nil then
        raise Exception.Create('Cannot create client socket to ' + fDeviceName);

      fSendSocket.Connect;
      if fSendSocket.Connected then
        fSendSocket.SendData(TEncoding.ASCII.GetBytes(sMessage))
      else
        raise Exception.Create('Cannot connect to ' + fDeviceName);

      Result := True;
    except
      on E: Exception do
        raise Exception.Create('Exception raised sending message: ' +
          E.Message);
    end;
  finally
    if fSendSocket.Connected then
      fSendSocket.Close;
    FreeAndNil(fSendSocket);
  end;
end;

procedure TBlueChatWriter.SetBlueDevice(Value: string);
begin
  if Value <> fDeviceName then
  begin
    fDeviceName := Value;
    fBlueDevice := FindBlueDevice(fDeviceName);
    if fBlueDevice = nil then
      raise Exception.Create('Cannot find device ' + fDeviceName);
  end;
end;

{ TBlueChatRead }

constructor TBlueChatReader.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  fTaskReader := nil;
  fReadSocket := nil;
  fServerSocket := nil;

  fReadUUID := StringToGuid('{14800546-CF05-481F-BE41-4EC0246D862D}');
end;

procedure TBlueChatReader.SetOnTextReceived(const Value: TTextEvent);
begin
  FOnTextReceived := Value;
end;

procedure TBlueChatReader.StartReader;
var
  Data: TBytes;
begin
  if fServerSocket <> nil then
    FreeAndNil(fServerSocket);

  fServerSocket := TBluetoothManager.Current.CurrentAdapter.CreateServerSocket
    ('FMXBlueChat', fReadUUID, False);

  fTaskReader := TTask.Create(
    procedure()
    begin
      fReadSocket := nil;
      while (fTaskReader.Status <> TTaskStatus.Canceled) do
      begin
        try
          fReadSocket := fServerSocket.Accept(cTimeOut);
          if (fReadSocket <> nil) and (fReadSocket.Connected) then
          begin
            Data := fReadSocket.ReceiveData;
            if Length(Data) > 0 then
            begin
              if Assigned(FOnTextReceived) then
                FOnTextReceived(Self, TEncoding.ASCII.GetString(Data),
                  fDeviceName);
            end;
          end;
        except
          on E: Exception do
          begin
            FreeAndNil(fReadSocket);
            raise Exception.Create('Exception raised receiving message: ' +
              E.Message);
          end;
        end;
        FreeAndNil(fReadSocket);
      end;
    end);
  fTaskReader.Start;
end;

procedure TBlueChatReader.StopReader;
begin
  if fTaskReader <> nil then
    if fTaskReader.Status <> TTaskStatus.Canceled then
      fTaskReader.Cancel;
end;

end.

A interface visual, por sua vez, é algo bastante simples. Estou certo que você vai compreender facilmente como tudo está funcionando investigando o exemplo que estou disponibilizando nos links abaixo, mas o essencial mesmo está nestas classes.



About
Gold User, Rank: 91, Points: 4
Lead Software Consultant, Latin America

Comments

Check out more tips and tricks in this development video: